!set n=$counter
checkfile=$checkdir/coord.proc
ss=!record 13 of lang/remarks.$taal
question$n=$ss
exotext=!record 25 of lang/remarks.$taal
sometext=!record 26 of lang/remarks.$taal
exotext=<p><a onmouseover="return escape('$sometext')">$exotext
helptext=$empty
F=f\left(x\right)\,\,=\,\,

R=$level
!if $level=0
    R=$counter
!endif    
	
a=!randitem 2,3,4,5,6,7,-2,-3,-4,-5,-6,-7
b=!randitem 2,4,6  
c=!randitem 2,3,4,5,6,7,8,9,10
d=!randitem 3,4,5,6,7,8,9,10   
x=!randitem -4,-3,-2,-1,0,1,2,3,4	
g=$[$d-1]

pm=!randitem +,-
mp=!randitem +,-
slope=!record 11 of lang/remarks.$taal


!if $R = 1
    functie=$a*x^$b 
    y=$[$a*($x)^$b]
    sommen=!exec pari A=deriv($functie ,x)\
    printtex(deriv($functie,x))\
    subst(A,x,$x)
    helling=!line 3 of $sommen
    afgeleide=!line 2 of $sommen
    formula$n=\left\{\begin{array}{l}$F $a\cdot x^{$b} \\ \\ $slope = $helling\end{array}
!endif
	
!if $R = 2
    functie=$a*x^$b $pm $c*x $mp $d
    y=$[$a*($x)^$b $pm $c*($x) $mp $d]
    sommen=!exec pari A=deriv($functie ,x)\
    printtex(deriv($functie,x))\
    subst(A,x,$x)
    
    helling=!line 3 of $sommen
    afgeleide=!line 2 of $sommen
    formula$n=\left\{\begin{array}{l}$F $a\cdot x^{$b} $pm $c\cdot x $mp $d\\ \\ $slope = $helling\end{array}
!endif

!if $R >2
    x=!randitem -3,-2,-1,1,2,3
    functie=$a $pm $c/x^2
    sommen=!exec pari $a $pm $c/($x)^2\
    A=deriv($functie ,x)\
    printtex(deriv($functie,x))\
    subst(A,x,$x)
    
    y=!line 1 of $sommen
    helling=!line 4 of $sommen
    afgeleide=!line 3 of $sommen
    formula$n=\left\{\begin{array}{l}$F $a  $pm \frac{$c}{x^2} \\ \\ $slope = $helling\end{array}
!endif    

answer$n=$x,$y
texanswer$n=\left\{\begin{array}{l}f'(x) = $afgeleide \\ \\ $slope \, =\, $helling  \end{array} \rightarrow \\ \\ $afgeleide = $helling  \rightarrow  \\ \\ \left[\begin{array}{l} x_{p}= $x \\  y_{p}= $y \end{array} \rightarrow \left( $x : $y \right) 

!if $image=1
    plot=1
    draw=0
    XSIZE=0.6
    YSIZE=0.6
    x1=$[-1*(abs($x)) -2]
    x2=$[abs($x) + 2]
    y1=$[-1*(abs($y))-30] 
    y2=$[(abs($y))+30] 
    Yrange=[$y1:$y2]
    Xrange=[$x1:$x2]
    linetext=!record 12 of lang/remarks.$taal
    raaklijn=($helling)*x + ($y - (($helling)*($x)))
    image_settings$n=size 0.6,0.6; noborder ; zeroaxis linetype 3 ; tmargin 1 ; rmargin 1 ; grid xtics ytics mxtics
    image$n= $Xrange $Yrange $functie title "f(x)" ,$raaklijn title "$linetext"
!endif    
