#sqrt(2)*sqrt( pi)*erf(x/sqrt(2))/2
cols=15
rows=6
!if exam notin $session
    viewlogo=1
    logotext=een melkfabriek
    logo=<img src="$module_dir/gifs/melk.gif" width="180" alt="MMMMM">
!endif
    
!if $rounding<10
    rounding=1000
    !readproc $remarkdir/rounding.$taal
!endif

!set n=$counter
!if $subject=1
    var2=0
!endif
questiontype=0
math=0
mathview=0
image=0
formula$n=$empty
checkfile=exos/checkfile2.proc
helptext=$empty
!if $var2=0
    #@ Bereken de kans<br>Gebruik je <em>Grafische Rekenmachine</em>
    ding=!record 13 of lang/remarks.$taal
    #@ (met je grafische rekenmachine)
    exotext=!record 94 of lang/remarks.$taal
!else
    #@ Bereken de kans<br>Gebruik <em>het tabellenboekje</em>
    ding=!record 15 of lang/remarks.$taal
    #@ (met het tabellenboekje)
!endif
!if $level=0
    R=$counter
!else
    R=$level
!endif
# 25 onderwerpen
maxrec=!recordcnt lang/lijst1.$taal
nummer=!randint 1,$maxrec
onderwerp=!record $nummer of lang/lijst1.$taal
fabriek=!item 1 of $onderwerp
produkt=!item 2 of $onderwerp
verpakking=!item 3 of $onderwerp
fles=!item 4 of $onderwerp
volume=!item 5 of $onderwerp
verzameling=!replace internal @ by , in $volume
inhoud=!randitem $verzameling
sig1=!item 6 of $onderwerp
sig2=!item 7 of $onderwerp
afw=!randitem 1,2,3,4,5
mean=$[1000*$inhoud + $afw]
sigma=!randint $sig1,$sig2
sigma=$[$sigma/10]
P=<font size="+1"><b>P</b></font>
!if $R=1
    var1=1
    # antwoord is kans
    !if $var2=0
        Z=$[($inhoud*1000 - $mean)/$sigma]
    !else
        Z=$[round(100*(($inhoud*1000 - $mean)/$sigma))/100]
    !endif
    S=-10000
    ss=!record 16 of lang/remarks.$taal
    question$n=$ss
    #@ In een $fabriek wordt $produkt afgevuld in een $inhoud liter $verpakking .<br>\
    #@ De vulling van een $verpakking is normaal verdeeld met een gemiddelde van $mean ml<br>\
    #@ en een standaardafwijking van $sigma ml.<p>\
    #@ Bereken $ding de kans op een inhoud kleiner dan $inhoud liter.<br>$roundingtext
    answer$n=$[0.5*(erf($Z/sqrt(2))-erf($S/sqrt(2)))]      
    G=$[round($rounding*$(answer$n))/$rounding]      
    !if $var2=0
	rr=!record 17 of lang/remarks.$taal
	textanswer$n=$rr
	#@ $P(X&le;$inhoud)&asymp;$G<br>intypen in Ti83 <tt>normalcdf</tt>(-10000,$[1000*$inhoud],$mean,$sigma)
    !else
	rr=!record 18 of lang/remarks.$taal
	textanswer$n=$rr
	#@ $P(X&le;$inhoud)&asymp;$G<br><ul><li>Bereken de <tt>z-waarde</tt> : z=($[1000*$inhoud]-$mean)/$sigma &asymp; $[(1000*$inhoud-$mean)/$sigma]</li>\
	#@ <li>rond dit z-getal af op twee decimalen</li><li>Zoek de kans op in je tabellenboekje</li></ul>
    !endif
 !exit
!endif    
!if $R=2
    var1=1
    # antwoord is kans
    A=$[ceil($sigma)]
    extra=!randint $[-2*$A],$[2*$A]
    nieuw=$[$mean+$extra]
    !if $var2=0
        Z=$[($nieuw - $mean)/$sigma]
    !else
        Z=$[round(100*(($nieuw - $mean)/$sigma))/100]
    !endif
    S=10000
    ss=!record 19 of lang/remarks.$taal
    question$n=$ss
    #@ In een $fabriek wordt $produkt afgevuld in een $inhoud liter $verpakking .<br>\
    #@ De vulling van een $verpakking is normaal verdeeld met een gemiddelde van $mean ml<br>\
    #@ en een standaardafwijking van $sigma ml.<p>\
    #@ Bereken $ding de kans op een inhoud groter dan $nieuw ml.<br>$roundingtext     
    answer$n=$[0.5*(erf($S/sqrt(2))-erf($Z/sqrt(2)))]   
    G=$[round($rounding*$(answer$n))/$rounding]   
    !if $var2=0
	rr=!record 20 of lang/remarks.$taal
	textanswer$n=$rr
	#@ $P(X&gt;$nieuw)&asymp;$G<br>intypen in Ti83 <tt>normalcdf</tt>($nieuw,10000,$mean,$sigma)
    !else
	rr=!record 21 of lang/remarks.$taal
	textanswer$n=$rr	
	#@ $P(X&gt;$nieuw)&asymp;$G<br><ul><li>Bereken de <tt>z-waarde</tt> : z=($nieuw - $mean)/$sigma=$[($nieuw - $mean)/$sigma]</li>\
	<li>$P(Z&le;$Z)&asymp;$[1-$G] (in tabellenboekje)</li><li>$P(Z&gt;$Z)&asymp;1- $[1-$G]&asymp;$G </li><li>$P(X&gt;$nieuw)&asymp;$G</li></ul>
    !endif
 !exit
!endif    
!if $R=3
    A=$[ceil($sigma)]
    extra1=!randint $[$mean-2*$A],$mean
    extra2=!randint $mean,$[$mean+2*$A]
    !if $var2=0
        Z=$[($extra1 - $mean)/$sigma]
        ZZ=$[($extra2 - $mean)/$sigma]
    !else
        Z=$[round(100*(($extra1 - $mean)/$sigma))/100]
        ZZ=$[round(100*(($extra2 - $mean)/$sigma))/100]
    !endif
    S=1000
    ss=!record 22 of lang/remarks.$taal
    question$n=$ss
    #@ In een $fabriek wordt $produkt afgevuld in een $inhoud liter $verpakking .<br>\
    #@ De vulling van een $verpakking is normaal verdeeld met een gemiddelde van $mean ml<br>\
    #@ en een standaardafwijking van $sigma ml.<p>\
    #@ Bereken $ding de kans op een inhoud tussen $extra1 ml en $extra2 ml.<br>$roundingtext       
    answer$n=$[0.5*(erf($ZZ/sqrt(2))-erf($Z/sqrt(2)))]      
    G=$[round($rounding*$(answer$n))/$rounding]      
    !if $var2=0
	rr=!record 23 of lang/remarks.$taal
	textanswer$n=$rr
	#@ $P($extra1 &lt; X &le; $extra2)&asymp;$G<br>intypen in Ti83 <tt>normalcdf</tt>($extra1,$extra2,$mean,$sigma)
    !else
	rr=!record 24 of lang/remarks.$taal
	textanswer$n=$rr
	#@ $P($extra1 &lt; X &le; $extra2)&asymp;$G<br><ul><li>Bereken de twee <tt>z-waarden</tt> :<br>\
	#@ z=($extra2 - $mean)/$sigma=$[($extra2 - $mean)/$sigma]<br>\
	#@ z=($extra1 - $mean)/$sigma=$[($extra1 - $mean)/$sigma]</li>\
	#@ <li>$P(Z&le;$ZZ)- $P(Z&le;$Z)&asymp;$G (zoek de twee bijbehorende kansen in je tabellenboek en trek ze van elkaar af) </li><li>$P($extra1 &lt; X &le; $extra2)&asymp;$G</li></ul>
    !endif
 !exit
!endif    
!if $R>3
    var1=0
    # antwoord is getal geen kans
    A=$[ceil($sigma)]
    extra=!randint 0,$[2*$A]
    nieuw=$[$mean - $extra]
    keuze=!randitem 1,2
    choice=!record 25 of lang/remarks.$taal
    #@ meer,minder
    meer=!item $keuze of $choice
    !if $var2=0
        Z=$[($nieuw - $mean)/$sigma]
    !else
        Z=$[round(100*(($nieuw - $mean)/$sigma))/100]
    !endif
    aantal=!randint 30,60
    aantal=$[$aantal*100]
    S=5
    ss=!record 26 of lang/remarks.$taal
    question$n=$ss
    #@ In een $fabriek wordt $produkt afgevuld in een $inhoud liter $verpakking .<br>\
    #@ De vulling van een $verpakking is normaal verdeeld met een gemiddelde van $mean ml<br>\
    #@ en een standaardafwijking van $sigma ml.<p>\
    #@ Vandaag worden er $aantal $fles afgevuld.<br> Bereken $ding hoeveel $fles een inhoud hebben van\
    #@ $meer dan $nieuw ml.       
    !if $keuze=1
	# $meer=meer
	chance=$[0.5*(erf(1000/sqrt(2))-erf($Z/sqrt(2)))]
	answer$n=$[(round($aantal*(0.5*(erf(1000/sqrt(2))-erf($Z/sqrt(2))))))]   
    !else
	# $meer=minder
	chance=$[0.5*(erf($Z/sqrt(2))-erf(-1000/sqrt(2)))]
	answer$n=$[(round($aantal*(0.5*(erf($Z/sqrt(2))-erf(-1000/sqrt(2))))))]   
    !endif
    rr=$chance * $aantal &asymp; $(answer$n)
    textanswer$n=$rr
 !exit
!endif    

# answer$n=!exec pari (round($rounding*(intnum(x=$S,$Z,e^(-0.5*x^2)))/(sqrt(2*pi))))/(1.0*$rounding)
