n=$teller
nivo_title=6-tallig getallenstelsel    
!if $graad=0
    R=$teller
!else
    R=$graad
!endif        

latex=0
bewerking=bewerking2.proc
hint=Kijk even in de uitvoerige help-pagina's   
pijl=<img src=" $module_dir/gifs/rightarrow.gif ">
    !if $R=1
	##a is decimaal...
	getal$n=!randint 6,120
	GOED$n=!exec float_calc ibase=10\
	obase=6\
	$(getal$n) 
	
	antwoord$n=$(getal$n)<sub>t</sub>  $pijl  $(GOED$n)<sub>z</sub>
	somtekst$n=Gegeven het <b>decimale</b> getal $(getal$n) <br>ofwel <b>$(getal$n)<sub><small>t</small></b></sub> <br>Zet dit getal om naar het <b>Zestallig-stelsel</b>
     !exit
    !endif

    !if $R=2
	##a is decimaal...
	GOED$n=!randint 60,600
	getal$n=!exec float_calc ibase=10\
	obase=6\
	$(GOED$n)
		
	antwoord$n=$(getal$n)<sub>z</sub>  $pijl  $(GOED$n)<sub>t</sub>
	somtekst$n=Gegeven het <b>Zes-tallige</b> getal $(getal$n) <br>ofwel <b>$(getal$n)<sub>z</sub></b> <br>Zet dit getal om naar het <b>tien-tallige</b>-stelsel.
     !exit
    !endif

    !if $R=3
	##a is decimaal...
	A=!randint 10,60
	B=!randint 10,60
	GOED$n=$[$A+$B]
	A$n=!exec float_calc ibase=10\
	obase=6\
	$A
	B$n=!exec float_calc ibase=10\
	obase=6\
	$B
	
	antwoord$n=$(A$n)<sub>z</sub>+$(B$n)<sub>z</sub>  $pijl  $(GOED$n)<sub>t</sub>
	somtekst$n=Bereken deze <b>zes-tallige</b> som:<br>\
	$(A$n)<sub>z</sub>&nbsp;+&nbsp;$(B$n)<sub>z</sub><br>\
	Geef je antwoord in het <b>tien-tallig</b> stelsel
     !exit
    !endif

    !if $R=4
	##a, b en goed zijn decimaal...
	a=!randint 60,600
	b=!randint 60,600
	pm=!randitem +,-
	!if $a>$b
	    A=$a
	    B=$b
	!else
	    A=$b
	    B=$a
	!endif
	goed=$[$A $pm $B]
	A$n=!exec float_calc scale=5 \
	ibase=10\
	obase=6\
	$A
	
	B$n=!exec float_calc scale=5 \
	ibase=10\
	obase=6\
	$B 
	
	GOED$n=!exec float_calc scale=5 \
	ibase=10\
	obase=6\
	$goed 
	
	antwoord$n=$(A$n)<sub>z</sub> $pm $(B$n)<sub>z</sub> $pijl  $(GOED$n)<sub>z</sub>
	somtekst$n=Bereken de volgende <b>Zestallige</b> som<br>\
	$(A$n)<sub>z</sub> $pm $(B$n)<sub>z</sub><br>\
	Geef je antwoord <b>ook</b> in het <b>zes-tallig</b> stelsel.
     !exit
    !endif

    !if $R>4
	a=!randint 6,60
	b=!randint 6,60
	goed=$[$a*$b]
	A$n=!exec float_calc scale=5 \
	ibase=10\
	obase=6\
	$a
	B$n=!exec float_calc scale=5 \
	ibase=10\
	obase=6\
	$b 
	GOED$n=!exec float_calc scale=5 \
	ibase=10\
	obase=6\
	$goed 
	
	antwoord$n= $(A$n)<sub>z</sub> &times; $(B$n)<sub>z</sub> $pijl  $(GOED$n)<sub>z</sub>
	somtekst$n=Bereken de volgende <b>Zestallige</b> som<br>\
	$(A$n)<sub>z</sub> &times; $(B$n)<sub>z</sub><br>\
	Geef je antwoord <b>ook</b> in het <b>zes-tallig</b> stelsel.
     !exit
    !endif



